DIY愛好者-Windows檔案保護專家 v1.0正式版
在發佈正式版之前，先說幾句：
首先感謝幫助我最大的朋友「猜猜鳥」，感謝你提供了很有用處的方法，現在終於可以完善這個工具。還有感謝「江山」提供了不少參考意見和信息，沒有他們的幫助也就沒有這個工具的今天。最後感謝那些一直支援我的朋友們，沒有你們的支援，小弟也不敢拿出自己的作品也大家分享，謝謝支援^^ 複製內容到剪貼板
代碼:
@echo off
rem Written by heroest
rem Feb 17th,2006
setlocal
color 0b
echo ===============================================================
echo.
echo Windows檔案保護專家 v1.0
echo.
echo.
echo 說明：本程序可以有效的保護重要的檔案不被刪除或洩露。
echo 加入了刪除文檔的代碼，可以刪除那些被保護的文檔
echo 版權沒有，歡迎盜版!
echo ===============================================================
:start
echo.
echo 建立檔案保護檔案夾 c:\FileLocker
if not exist c:\FileLocker..\nul md c:\FileLocker..\
echo 歡迎使用windwos保護專家 v1.0,請選擇選項（1,2,3,4,5,q）;
echo 1.讀取加密的文檔
echo 2.存儲保密文檔
echo 3.建立秘密存儲文檔
echo 4.刪除保密文檔
echo 5.刪除FileLocker
echo q.推出
echo.
set /p choice=
if {%choice%}=={} goto start
if /i %choice%==1 goto djm
if /i %choice%==2 goto cjm
if /i %choice%==3 goto jjm
if /i %choice%==4 goto sjm
if /i %choice%==5 goto df
if /i %choice%==q goto quit
goto start
rem========================加入秘密檔案夾==========================
:jjm
echo.
echo 準備建立秘密檔案夾...
echo 請輸入密碼:
set /p pass2c=
if {%pass2c%}=={} goto jjm
echo 開始根據密碼建立保密檔案夾......
md "c:\FileLocker..\%pass2c%..\"
echo 建立了保護檔案夾!
echo.
goto start
rem ======================「加入」部分結束=========================
rem
rem =====================存儲資料部分==============================
:cjm
echo.
echo 準備存儲保密檔案...
echo 請輸入密碼：
set /p pass=
if {%pass%}=={} goto cjm
if exist c:\FileLocker..\%pass%..\nul goto noerror
echo 發生錯誤，未發現建立加密保護檔案夾！
goto start
:noerror
md "%userprofile%\桌面\Ready2Lock"
echo 請將你需要保護的檔案複製到桌面上的Ready2Lock檔案夾內(被保存的檔案不能含有檔案夾）
echo 注意：開始保護後會刪除原檔案!
echo 按任意鍵開始保護檔案.......
pause > nul
echo 開始保護到C:\FileLocker檔案夾內.........
copy "%userprofile%\桌面\Ready2Lock\*.*" "c:\FileLocker..\%pass%..\"
echo 保護完成，刪除原檔案........
del "%userprofile%\桌面\Ready2Lock\*.*" /Q
rd "%userprofile%\桌面\Ready2Lock"
echo 所有保護完成!
ping 127.0.0.1 -n 3 >nul
cls
goto start
rem ==========================存儲部分結束=======================
rem
rem ===========================讀取資料部分======================
:djm
echo.
echo 準備讀取保密檔案...
echo 請輸入密碼：
set /p pass2=
if {%pass2%}=={} goto djm
if not exist c:\FileLocker..\%pass2%..\nul echo 發生錯誤或不存在保護文檔 & goto djm
echo 開始讀取被保護的資料.......
if not exist "%userprofile%\桌面\Unlocked\nul" md "%userprofile%\桌面\Unlocked"
copy "c:\FileLocker..\%pass2%..\*.*" "%userprofile%\桌面\Unlocked"
echo 已經解密到桌面上的Unlocked檔案夾內.........
ping 127.0.0.1 -n 3 >nul
goto start
rem ========================讀取資料部分結束=======================
rem
rem ========================刪除目錄部分===========================
rem 此部分特別感謝"猜猜鳥"教會了我新的知識，謝謝了！
rem 感謝"江山"的提供了寶貴的意見
rem 也感謝支援我的朋友們，沒有你們的鼓勵，小弟也不敢斗膽發表自己的作品
:sjm
echo.
echo.
echo 準備刪除秘密文檔.......
echo 請輸入密碼：
set /p pass2del=
if {%pass2del%}=={} goto sjm
echo 開始刪除被保護檔案夾
rmdir /s "c:\FileLocker..\%pass2del%..\" /Q
echo 已經刪除被保護檔案.......
goto start
rem ============================刪除部分結束======================
rem
rem ===================Del FileLocker==============================
:df
echo.
echo 請刪除之前確認FileLocker裡面沒有任何秘密文檔.(y/n)
set /p yesorno=
if /i %yesorno%==y goto start2del
if /i %yesorno%==n goto sjm
goto df
:start2del
echo 開始刪除FileLocker..........
rd "c:\FileLocker..\" >nul
if exist c:\FileLocker..\nul echo **刪除失敗，可能FileLocker裡有別的秘密文檔。**& goto fail
echo 成功刪除!
:fail
ping 127.0.0.1 -n 3 >nul
goto start
rem ================Del Filelocker End====================
:quit
echo 感謝使用Windows檔案保護專家 v1.0!
echo 按任意鍵退出本程序.
pause > nul
exit
